[程序分享] SAS基礎(chǔ)宏之10：GetDataSetInfoInLib [推廣有獎(jiǎng)]

16關(guān)注
79粉絲

學(xué)科帶頭人

還不是VIP/貴賓

TA的文庫(kù) 其他...

R相關(guān)

經(jīng)濟(jì)學(xué)相關(guān)

金融工程

威望: 1 級(jí)
論壇幣: 16330 個(gè)
通用積分: 8.5797
學(xué)術(shù)水平: 372 點(diǎn)
熱心指數(shù): 394 點(diǎn)
信用等級(jí): 341 點(diǎn)
經(jīng)驗(yàn): 15297 點(diǎn)
帖子: 1194
精華: 1
在線時(shí)間: 1331 小時(shí)
注冊(cè)時(shí)間: 2007-1-11
最后登錄: 2023-12-15

樓主

playmore 發(fā)表于 2013-4-20 21:32:56 |只看作者 |壇友微信交流群|倒序 |AI寫論文

是否 +2 論壇幣

k人參與回答

經(jīng)管之家送您一份

應(yīng)屆畢業(yè)生專屬福利!

求職就業(yè)群

趙安豆老師微信：zhaoandou666

經(jīng)管之家聯(lián)合CDA

送您一個(gè)全額獎(jiǎng)學(xué)金名額~ !

立即領(lǐng)取

感謝您參與論壇問(wèn)題回答

經(jīng)管之家送您兩個(gè)論壇幣！

+2 論壇幣

得到指定Library里的數(shù)據(jù)集列表
可以導(dǎo)出至新的數(shù)據(jù)集或指定txt文件

%macro GetDataSetInfoInLib(LibName,Filter,TargetTable,OutFilePath,Detail);
/**********************************************************************/
/* 此宏用于獲得目標(biāo)邏輯庫(kù)下所有數(shù)據(jù)集的信息，并將此信息保存至SAS表格 */
/* 或?qū)С鲋羣xt文件中。其中，LibName是指定的邏輯庫(kù)；Filter是數(shù)據(jù)集過(guò)濾 */
/* 設(shè)置，支持_和%通配符，若需要導(dǎo)出所有數(shù)據(jù)集列表，可以設(shè)置為空； */
/* TargetTable是保存數(shù)據(jù)集信息的SAS表格，若不需要生成，可以設(shè)為空； */
/* OutFilePath是導(dǎo)出txt文件的路徑，若不需要導(dǎo)出，可以設(shè)為空；Detail是 */
/* 標(biāo)記變量，=Yes表示導(dǎo)出數(shù)據(jù)集列表詳情，否則=No。 */
/* */
/* 最終得到的是含有目標(biāo)邏輯庫(kù)下所有數(shù)據(jù)集信息的SAS表格和存于指定路徑 */
/* 的txt文件。 */
/* */
/* Created on 2013.2.23 */
/* Modified on 2013.4.3 */
/**********************************************************************/
/* 檢查TargetTable和OutFilePath的非同時(shí)為空性 */
%if &TargetTable EQ %STR() AND &OutFilePath EQ %STR() %then %do;
%put ERROR: The TargetTable and OutFilePath should not be blank simultaneously, please check it again.;
%goto exit;
%end;
%if &TargetTable EQ %STR() %then %let TargetTable=GDSIIL_Temp;
/* 檢查OutFilePath的合法性，若后綴不存在或非TXT，則改為TXT */
%if &OutFilePath NE %STR() %then %do;
%if %SYSFUNC(FIND(&OutFilePath,%STR(.))) EQ 0 %then %do;
%let OutFilePath=%SYSFUNC(CATS(&OutFilePath,%STR(.TXT)));
%end;
%else %if %SYSFUNC(FIND(&OutFilePath,%STR(.))) NE 0 AND %UPCASE(%SCAN(&OutFilePath,-1,%STR(.))) NE TXT %then %do;
%let OutFilePath=%SYSFUNC(CATS(%SUBSTR(&OutFilePath,1,%LENGTH(&OutFilePath)-%LENGTH(%SCAN(&OutFilePath,-1,%STR(.)))),TXT));
%end;
%end;
/* 檢查輸入路徑下是否存在同名文件，若存在則刪除 */
%if &OutFilePath NE %STR() %then %do;
%ChkFile(&OutFilePath);
%end;
/* 檢查Detail的合法性 */
%if &Detail EQ %STR() %then %let Detail=No;
%if %UPCASE(&Detail) NE YES AND %UPCASE(&Detail) NE NO %then %do;
%put ERROR: The Detail should be Yes or No, case insensitive and without quotes.;
%goto exit;
%end;
/* 開始進(jìn)行計(jì)算 */
proc sql noprint;
create table &TargetTable as
select * from SASHELP.VTABLE
where libname EQ UPCASE("&LibName.")
%if %UPCASE(&Filter) NE %STR() %then %do;
and memname like UPCASE("&Filter.");
%end;
%else %do;
;
%end;
quit;
%if %UPCASE(&Detail) EQ NO %then %do;
data &TargetTable;
set &TargetTable(keep=libname memname);
run;
%end;
%if &OutFilePath NE %STR() %then %do;
%ExportToDelimitedFile(SourceTable=&TargetTable,
Delimiter='09'x,
PutNames=Yes,
OutFilePath=&OutFilePath);
%end;
/* 如需要在SAS的Output窗口中打印文件列表，請(qǐng)取消如下注釋 */
/*proc print data=&TargetTable;*/
/*title1 "Files identified through saved file";*/
/*run;*/
/* 刪除不必要的表格 */
proc datasets lib=work nolist;
delete GDSIIL_:;
quit;
%exit:
%mend;
%macro Demo();
%let LibName=Zheng;
%let Filter=r%; /* 文件過(guò)濾設(shè)置，若需要導(dǎo)出所有文件列表，則設(shè)置為空即可，即Filter=; */
%let TargetTable=FileList; /* 若不需要生成包含文件列表的SAS表格，則設(shè)為空，大小寫不敏感 */
%let OutFilePath=d:\Temp\abc.txt; /* 若不需要導(dǎo)出文件列表txt文件，則設(shè)為空，大小寫不敏感 */
%let Detail=Yes; /* =Yes表示在導(dǎo)出文件列表txt文件中包含InDirPath的詳情，否則=No，大小寫不敏感 */
%GetDataSetInfoInLib(&LibName,&Filter,&TargetTable,&OutFilePath,&Detail);
%mend;